2.16. Wat is het percentage ingezette uren personeel in loondienst (PIL) en personeel niet in loondienst (PNIL)?

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• Inhuurovereenkomst
• Uitzendovereenkomst
• Werkovereenkomst afspraak

Relaties

• gedefinieerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.16
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT 
12    ?Periode
13    ("Totaal organisatie" AS ?Indeling)
14    (SUM(?uren * ?pnil) AS ?Ingezette_uren_PNIL)
15    (SUM(?uren * ?pil) AS ?Ingezette_uren_PIL)
16	(ROUND(10000*SUM(?uren * ?pnil)/SUM(?uren)) / 100 AS ?Procent_ingezette_uren_PNIL) 
17	(ROUND(10000*SUM(?uren * ?pil)/SUM(?uren)) / 100 AS ?Procent_ingezette_uren_PIL) 
18{
19    #BIND(2024 AS ?jaar)
20    VALUES ?kw { 0 1 2 3 4 }
21
22    BIND( xsd:date(CONCAT(STR(?jaar), "-",
23            IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
24        )) AS ?p_start )
25    BIND( xsd:date(CONCAT(STR(?jaar), "-",
26            IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
27        )) AS ?p_eind )
28
29    BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
30
31    VALUES ?type_overeenkomst { onz-pers:ArbeidsOvereenkomst onz-pers:InhuurOvereenkomst onz-pers:UitzendOvereenkomst }
32    
33    ?overeenkomst 
34        a ?type_overeenkomst ; # PIL (ArbeidsOvereenkomst) en PNIL (Inhuur-/UitzendOvereenkomst)
35        onz-pers:heeftOpdrachtnemer ?persoon ;
36        onz-g:hasPart ?overeenkomst_afspraak .
37    ?overeenkomst_afspraak
38        a onz-pers:WerkOvereenkomstAfspraak ;
39        onz-g:startDatum ?start_afspraak .
40    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
41    FILTER(?start_afspraak <= ?p_eind && ((?eind_afspraak >= ?p_start) || (!BOUND(?eind_afspraak))))
42    
43    ?inzet
44        a onz-pers:GewerktePeriode ;
45        onz-g:definedBy ?overeenkomst ;
46        onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
47        onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?uren .
48    
49    BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
50    FILTER(?start_inzet >= ?p_start && ?start_inzet <= ?p_eind)
51    FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
52    
53    BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomst, 1, 0) AS ?pil)
54    BIND(1 - ?pil AS ?pnil)
55}
56GROUP BY ?Periode 
57ORDER BY ?Periode
58